comment:
This sample script implements an environmental Kuznets curve.
The basic IPAT equation is used, but the technology factor "T"
varies with income following a Kuznets-like shape. The curve
has an "inverted-U" at low-to-moderate income, then has a long
tail. The income elasticities at low incomes and on the high-income
tail are parameters in the script (lowElast and -1 * highElast).

The script also features relative income convergence. The GDP per capita
growth rate for the high-income region is set as an exogenous
parameter, with other regions then converging towards the high-income
region at a rate convRate. The formula for convergence is similar to
the one in Barro's regression:

   d ln(y)/dt = r - k * ln(y/y_high) + ...

where all additional terms (...) are assumed to be zero. In the script,
the parameter r is highGR, and k is convRate. Because no factors are
assumed to hinder income convergence (the "..." in the equation), the
UN low population projection is used.
:comment

base year 2000
scenario years 2010 to 2050 by 10

# More regions can be added, as long as:
#  a) populations are specified
#  b) base-year data are specified
#  c) There is always a "High Income" region
dimension region 'Low Income' 'High Income'

var A{region} T{region}
summvar P{region} I{region}

# Income growth parameters
num highGR = <1.5%>
num convRate = <2.0%>

# Environmental Kuznets Curve (EKC) parameters
# Formula is:
#   T = (1 + highElast/lowElast) * Tmax * z^lowElast /
#         (highElast/lowElast + z^(lowElast + highElast))
# where z is A/Amax
num Tmax = 1000  # Absolute level doesn't matter
num Amax = <3500> # Income where EKC hits its maximum Tmax
num lowElast = <1.0>
num highElast = <1.0>

##
## Basic data
##
# UN Pop Prospects for "More Developed" and "Less Developed"
# countries (millions), low variant, 2002 revision
# http://esa.un.org/unpp
P{region = 'Low Income'} = 4877, 5478, 5952, 6268, 6385, 6325
P{region = 'High Income'} = 1193, 1211, 1207, 1187, 1144, 1083

# Average income per capita (PPP$/cap)
# From UNDP HDR 2002
# "High Income" and weighted average of "Middle and Low Income"
#    for year 2000, in PPP US$.
A.0{region = 'Low Income'} = 3970
A.0{region = 'High Income'} = 27640

##
## Income growth
##
# Convergence calculation
var z{region}
:: ln0(A/A{region = 'High Income'}) -> z
:: >> gr(-convRate) -> z

# Apply growth rate
:: exp(z) >> gr(highGR) -> A

##
## Technology factor, using environmental Kuznets curve
##
# Recycle the intermediate variable z
:: A/Amax -> z
:: (1 + highElast/lowElast) * Tmax * z^lowElast / \
      (highElast/lowElast + z^(lowElast + highElast)) -> T

##
## The IPAT equation
##
:: P * A * T -> I

##
## Report results
##
summvar totGDP totPop
summarize P * A as totGDP
summarize P as totPop
report totGDP/totPop as "GWP per capita ($/cap)"

summvar Itot
summarize I as Itot

report 100 * Itot/Itot.0 as "Impact Index (2000 = 100)"
report 100 * (Itot/totGDP)/(Itot/totGDP).0 as \
             "Impact per GDP Index (2000 = 100)"

report A as "GDP per capita ($/cap)"
report 100 * I/Itot.0 as "Regional Impact Index (2000 = 100)"