base year 2000
scenario years 2010 to 2050 by 10

dimension scenario 'Tech Optimist Exponential' 'Tech Optimist Linear' \
                   'Tech Pessimist' 'Intermediate View'

load _Loglet from 'IPATS_standard' as Logistic

##
## World population, UN medium variant, 2002 revision (millions)
##
summvar Population = 6070.581, 6830.283, 7540.237, \
                     8130.149, 8593.591, 8918.724

##
## Economic growth, change in food consumption
##
ratio Income = gr(1.80%)
ratio Appetite = 1/Income^0.7
ratio NonFood = gr(0.0%)

##
## Yield changes & land use
##
var Yield{scenario}, Cropland{scenario}

Yield.0 = 100		# index
Cropland.0 = 1500	# million ha (approximate)

##
## Yield scenarios
##

##### Waggoner and Ausubel: Tech Optimist Exponential's exponential yield increase #####
:: >> gr(1.70%) -> Yield{scenario = 'Tech Optimist Exponential'}

##### Dyson: Tech Optimist Linear's linear yield increase #####
:: 2.711 + 0.0426 * (y - 1990) >>-> Yield{scenario = 'Tech Optimist Linear'}

##### Saturated yields #####
# Follow a logistic path of increasing, then saturating yields
var tempYld

# Single logistic:
#   midpoint at 1990
#   saturate at 220 (so max yield index is 220 + 80 = 300% of 1961 level)
#   characteristic duration of 68 years (so from roughly 1956 to 2024)
call Logistic using tempYld \
                  218.9 67.5 1991

# Logistic starts from base of 80, not from 0, so add 80 to drive total yield
:: 80 + tempYld >>-> Yield{scenario = 'Tech Pessimist'}

##### Intermediate View #####
# Like "Tech Pessimist," but add two further logistics for 
# future advances
# Use:
#   midpoint of 2020 and 2050
#   additional yield increase equal to one-half, then one-quarter the
#       first logistic
#   characteristic duration one-half as long as first logistic
call Logistic using tempYld \
                  218.9 67.5 1991 \
                 <110   35   2020> \
                 <55    35   2050>

# Logistic starts from base of 80, not from 0, so add 80 to drive total yield
:: 80 + tempYld >>-> Yield{scenario = 'Intermediate View'}


##
## Changes in cropland use
##
:: Population >> Income * Appetite * NonFood / Yield -> Cropland

##
## Report results
##
report Yield as "Yield (2000 = 100)"
report 100 * Cropland/Cropland.0 as "Cropland (2000 = 100)"
report Cropland - Cropland.0 as "Change in cropland (Mha)"